{ lib, pkgs, ... }:

with pkgs; callPackage python3Packages.buildPythonPackage rec {
  pname = "xborders";
  version = "3.4"; # in version.txt

  src = fetchFromGitHub {
    owner = "deter0";
    repo = "xborder";
    rev = "8a031736c9e89a031428f33adcd42da7512d558e";
    sha256 = "sha256-y+Cip5fcDqnJr0aI3jqJMTt6iCV0faunM+Gk6HFZ5iA=";
  };

  buildInputs = [
    libwnck
    gtk3
    libnotify
  ];

  nativeBuildInputs = [
    wrapGAppsHook
    gobject-introspection
  ];

  propagatedBuildInputs = with python3Packages; [
    pycairo
    requests
    pygobject3
  ];

  preBuild = ''
    cat >setup.py <<'EOF'
    from setuptools import setup
    setup(
      name='${pname}',
      version='${version}',
      author='deter0',
      description='${meta.description}',
      install_requires=['pycairo', 'requests', 'PyGObject'],
      scripts=[
        'xborders',
      ],
    )
    EOF
  '';

  meta = with lib; {
    description = "Active window border replacement for window managers.";
    homepage = "https://github.com/deter0/xborder";
    license = licenses.unlicense;
    maintainers = with maintainers; [ elnudev ];
    platforms = platforms.linux;
  };
}